Az Excel VLOOKUP függvény használata -

Összegzés

A VLOOKUP egy Excel függvény, amely függőlegesen rendezett táblázatban keresi az adatokat. A VLOOKUP támogatja a hozzávetőleges és pontos egyeztetést, a helyettesítő karaktereket (*?) A részleges egyezésekhez. A keresési értékeknek meg kell jelenniük a táblázat első oszlopában, amelyet átadtak a VLOOKUP fájlba.

Célja

Keressen egy táblában egy értéket az első oszlopnak megfelelő megfeleltetéssel

Visszatérési érték

Az egyező érték egy táblázatból.

Szintaxis

= VLOOKUP (érték, táblázat, col_index, (range_lookup))

Érvek

érték - A táblázat első oszlopában keresendő érték.
tábla - A táblázat, amelyből lekérhet egy értéket.
col_index - A táblázat oszlopa, ahonnan értéket lehet lekérni.
range_lookup - (opcionális) IGAZ = hozzávetőleges egyezés (alapértelmezett). HAMIS = pontos egyezés.

Változat

Excel 2003

Használati megjegyzések

A VLOOKUP egy Excel függvény, amely függőlegesen rendezett táblákból szerez adatokat. A keresési értékeknek meg kell jelenniük a táblázat első oszlopában, amelyet átadtak a VLOOKUP fájlba. A VLOOKUP támogatja a hozzávetőleges és pontos egyeztetést, a helyettesítő karaktereket (*?) A részleges egyezésekhez.

V függőleges

A VLOOKUP célja, hogy információkat szerezzen egy ilyen rendszerű táblázatból:

A B oszlopban található Rendelési számot keresési értékként használva a VLOOKUP bármely megrendeléshez megszerezheti az ügyfél-azonosítót, az összeget, a nevet és az állapotot. Például az 1004-es megrendelés ügyfélnevének megszerzéséhez a képlet a következő:

=VLOOKUP(1004,B5:F9,4,FALSE) // returns "Sue Martin"

Vízszintes adatokhoz használhatja a HLOOKUP, INDEX és MATCH vagy XLOOKUP elemeket.

A VLOOKUP oszlopszámokon alapul

A VLOOKUP használatakor képzelje el, hogy a táblázat minden oszlopa balról kezdve számozott. Ha egy adott oszlopból szeretne értéket kapni, adja meg a megfelelő számot "oszlopindexként". Például az oszlopindex az utónév lekéréséhez 2:

A vezetéknév és az e-mail cím a 3. és 4. oszlopban tölthető le:

=VLOOKUP(H3,B4:E13,2,FALSE) // first name =VLOOKUP(H3,B4:E13,3,FALSE) // last name =VLOOKUP(H3,B4:E13,4,FALSE) // email address

A VLOOKUP csak jól néz ki

A VLOOKUP csak jobbra nézhet. A lekérni kívánt adatok (eredményértékek) bármely oszlopban megjelenhetnek a keresési értékektől jobbra:

Ha balra kell keresnie az értékeket, lásd: INDEX és MATCH, vagy XLOOKUP.

Pontos és hozzávetőleges egyezés

A VLOOKUP-nak kétféle illesztési módja van, pontos és közelítő. Az egyezést vezérlő argumentum neve: " range_lookup ". Ez egy zavaros név, mert úgy tűnik, hogy köze van az A1: A10 cellatartományokhoz. Valójában a „tartomány” ebben az esetben utal a „értéktartomány” - ha tartományban_keres IGAZ, VLOOKUP fog egyezni egy értéktartomány helyett egy adott érték. Jó példa erre a VLOOKUP használata az osztályzatok kiszámításához.

Fontos megérteni, hogy a range_lookup alapértelmezett értéke IGAZ, ami azt jelenti, hogy a VLOOKUP alapértelmezés szerint hozzávetőleges egyezést fog használni, ami veszélyes lehet. Állítsa a range_lookup értéket FALSE értékre a pontos egyezés kikényszerítéséhez:

=VLOOKUP(value, table, col_index) // approximate match (default) =VLOOKUP(value, table, col_index, TRUE) // approximate match =VLOOKUP(value, table, col_index, FALSE) // exact match

Megjegyzés: A FALSE helyett nulla (0) is megadható a pontos egyezéshez.

Pontos mérkőzés

A legtöbb esetben valószínűleg a VLOOKUP-ot szeretné használni pontos egyezési módban. Ennek akkor van értelme, ha van egy egyedi kulcs, amelyet keresési értékként használhat, például a film címe az adatokban:

A H6 képlete az Év megtalálásához a film címe pontos egyezésén alapul:

=VLOOKUP(H4,B5:E9,2,FALSE) // FALSE = exact match

Hozzávetőleges mérkőzés

In cases when you want the best match , not necessarily an exact match , you'll want to use approximate mode. For example, below we want to look up a commission rate in the table G5:H10. The lookup values come from column C. In this example, we need to use VLOOKUP in approximate match mode, because in most cases an exact match will never be found. The VLOOKUP formula in D5 is configured to perform an approximate match by setting the last argument to TRUE:

=VLOOKUP(C5,$G$5:$H$10,2,TRUE) // TRUE = approximate match

VLOOKUP will scan values in column G for the lookup value. If an exact match is found, VLOOKUP will use it. If not, VLOOKUP will "step back" and match the previous row.

Note: data must be sorted in ascending order by lookup value when you use approximate match mode with VLOOKUP.

First match

In the case of duplicate values, VLOOKUP will find the first match when the match mode is exact. In screen below, VLOOKUP is configured to find the price for the color "Green". There are three entries with the color Green, and VLOOKUP returns the price for the first entry, $17. The formula in cell F5 is:

=VLOOKUP(E5,B5:C11,2,FALSE) // returns 17

Wildcard match

The VLOOKUP function supports wildcards, which makes it possible to perform a partial match on a lookup value. For instance, you can use VLOOKUP to retrieve values from a table after typing in only part of a lookup value. To use wildcards with VLOOKUP, you must specify exact match mode by providing FALSE or 0 for the last argument, range_lookup . The formula in H7 retrieves the first name, "Michael", after typing "Aya" into cell H4:

=VLOOKUP($H$4&"*",$B$5:$E$104,2,FALSE)

Read a more detailed explanation here.

Two-way lookup

Inside the VLOOKUP function, the column index argument is normally hard-coded as a static number. However, you can also create a dynamic column index by using the MATCH function to locate the right column. This technique allows you to create a dynamic two-way lookup, matching on both rows and columns. In the screen below, VLOOKUP is configured to perform a lookup based on Name and Month. The formula in H6 is:

=VLOOKUP(H4,B5:E13,MATCH(H5,B4:E4,0),0)

For more details, see this example.

Note: In general, INDEX and MATCH is a more flexible way to perform two-way lookups.

Multiple criteria

The VLOOKUP function does not handle multiple criteria natively. However, you can use a helper column to join multiple fields together, and use these fields like multiple criteria inside VLOOKUP. In the example below, Column B is a helper column that concatenates first and last names together with this formula:

=C5&D5 // helper column

VLOOKUP is configured to do the the same thing to create a lookup value. The formula in H6 is:

=VLOOKUP(H4&H5,B5:E13,4,0)

For details, see this example.

Note: INDEX and MATCH and XLOOKUP are more robust ways to handle lookups based on multiple criteria.

VLOOKUP and #N/A errors

If you use VLOOKUP you will inevitably run into the #N/A error. The #N/A error just means "not found". For example, in the screen below, the lookup value "Toy Story 2" does not exist in the lookup table, and all three VLOOKUP formulas return #N/A:

One way to "trap" the NA error is to use the IFNA function like this:

The formula in H6 is:

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"Not found")

The message can be customized as desired. To return nothing (i.e. to display a blank result) when VLOOKUP returns #N/A you can use an empty string like this:

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"") // no message

The #N/A error is useful because it tells you something is wrong. In practice, there are many reasons why you might see this error, including:

The lookup value does not exist in the table
The lookup value is misspelled, or contains extra space
Match mode is exact, but should be approximate
The table range is not entered correctly
You are copying VLOOKUP, and the table reference is not locked

More about VLOOKUP

More VLOOKUP examples
VLOOKUP videos
23 tips for using VLOOKUP

Other notes

Range_lookup controls whether value needs to match exactly or not. The default is TRUE = allow non-exact match.
Set range_lookup to FALSE to require an exact match and TRUE to allow a non-exact match .
If range_lookup is TRUE (the default setting), a non-exact match will cause the VLOOKUP function to match the nearest value in the table that is still less than value .
When range_lookup is omitted, the VLOOKUP function will allow a non-exact match, but it will use an exact match if one exists.
If range_lookup is TRUE (the default setting) make sure that lookup values in the first row of the table are sorted in ascending order. Otherwise, VLOOKUP may return an incorrect or unexpected value.
If range_lookup is FALSE (require exact match), values in the first column of table do not need to be sorted.