Összegzés
A teljes jövedelemadó több adótáblázat alapján történő kiszámításához használhatja a VLOOKUP és a kamatláb táblázatot, amely a példában látható módon van felépítve. A G5 képlete a következő:
=VLOOKUP(inc,rates,3,1)+(inc-VLOOKUP(inc,rates,1,1))*VLOOKUP(inc,rates,2,1)
ahol az "inc" (G4) és az "arányok" (B5: D11) tartományokat nevezik meg, és a D oszlop egy segítő oszlop, amely kiszámítja az összes zárójelben felhalmozott adót.
Háttér és összefüggések
Az amerikai adórendszer "progresszív", ami azt jelenti, hogy a magasabb adóköteles jövedelemmel rendelkező emberek magasabb szövetségi adókulcsot fizetnek. Az arányokat zárójelben értékelik, amelyet egy felső és alsó küszöb határoz meg. Az adott zárójelbe eső jövedelem összegét az adott zárójelnek megfelelő adókulccsal kell megadóztatni. Az adóköteles jövedelem növekedésével a jövedelmet több adósávon adózzák. Sok adófizető ezért több különböző adót fizet.
A bemutatott példában az adózási zárójelek és kulcsok az Egyesült Államokban a 2019-es adóévre vonatkozó egyszemélyes bejelentőkre vonatkoznak. Az alábbi táblázat az 50 000 dolláros adóköteles jövedelem kézi számítását mutatja:
| Zárójel | Számítás | Adó |
|---|---|---|
| 10% | (9 700 USD - 0 USD) x 10% | 970,00 USD |
| 12% | (39 475 USD - 9 700 USD) x 12% | 3573,00 USD |
| 22% | (50 000 USD - 39 475 USD) x 22% | 2315,50 USD |
| 24% | NA | 0,00 USD |
| 32% | NA | 0,00 USD |
| 35% | NA | 0,00 USD |
| 37% | NA | 0,00 USD |
A teljes adó tehát 6858,50 USD. (a bemutatott példában 6.859-ként jelenik meg).
Telepítési megjegyzések
1. Ez a képlet a VLOOKUP függvénytől függ "hozzávetőleges egyezési módban". Körülbelül egyezési módban a VLOOKUP átvizsgálja a táblázat keresési értékeit (amelyeket növekvő sorrendben kell rendezni), amíg magasabb értéket nem talál. Ezután "visszalép" és visszaad egy értéket az előző sorból. Pontos egyezés esetén a VLOOKUP visszaadja az illesztett sor eredményeit.
2. Annak érdekében, hogy a VLOOKUP lekérje a tényleges összesített adóösszegeket, ezeket a táblázatban segédoszlopként adtuk hozzá a D. oszlophoz. A D6-ban szereplő képlet, amelyet lemásoltunk:
=((B6-B5)*C5)+D5
Ez a képlet minden sorban a fenti sor árfolyamát alkalmazza az adott zárójelben szereplő jövedelemre.
3. Az olvashatóság érdekében a következő megnevezett tartományokat határozzuk meg: "inc" (G4) és "rate" (B5: D11).
Magyarázat
A G5-ben az első VLOOKUP úgy van konfigurálva, hogy a kumulatív adót marginális kulcson lehívja a következő bemenetekkel:
- A keresési érték "inc" (G4)
- A keresési táblázat "árak" (B5: D11)
- Oszlop száma 3, Halmozott adó
- Az egyezés típusa 1 = hozzávetőleges egyezés
VLOOKUP(inc,rates,3,1) // returns 4,543
50 000 dolláros adóköteles jövedelemmel a VLOOKUP, hozzávetőleges játékmódban, 39 475-et tesz ki, és 4543-at ad vissza, a teljes adó 39 475 dollárig.
A második VLOOKUP kiszámítja a fennmaradó adót:
(inc-VLOOKUP(inc,rates,1,1)) // returns 10,525
így számolva:
(50 000-39 475) = 10 525
Végül a harmadik VLOOKUP megkapja a (felső) marginális adókulcsot:
VLOOKUP(inc,rates,2,1) // returns 22%
Ezt meg kell szorozni az előző lépésben kiszámított jövedelemmel. A teljes képlet így oldódik meg:
=VLOOKUP(inc,rates,3,1)+(inc-VLOOKUP(inc,rates,1,1))*VLOOKUP(inc,rates,2,1) =4,543+(10525)*22% =6,859
Marginális és tényleges kamatlábak
A G6 cella tartalmazza a VLOOKUP segítségével kiszámított felső határmértéket:
=VLOOKUP(inc,rates,2,1) // returns 22%
A G7 tényleges adókulcsa a teljes adó osztva az adóköteles jövedelemmel:
=G5/inc // returns 13.7%
Megjegyzés: Jeff Lenning blogján futottam össze ezzel a képlettel az Excel Egyetemen. Remek példa arra, hogyan lehet a VLOOKUP hozzávetőleges módban használni, és arra is, hogy a VLOOKUP többször használható-e ugyanazon képletben.
